PARM filename,out=''                                                            
# This command file prints the first "filename" found in HPPATH.                
# Current limitation: POSIX named files or directory names in HPPATH are        
#   not supported.                                                              
                                                                                
#  Only append path to unqualified file names.                                  
if fsyntax('!filename') <> 'MPE' then                                           
   echo PRNT only supports simple MPE files.                                    
   return                                                                       
endif                                                                           
                                                                                
if pos('.','!filename') > 0 then                                                
   continue                                                                     
   print !filename,!out ;page=22                                                
   return                                                                       
endif                                                                           
                                                                                
# only use hppath for unqualified filenames                                     
setvar _prnt_i 0                                                                
setvar _prnt_match false                                                        
while not (_prnt_match) and &                                                   
      setvar(_prnt_tok,word("!hppath",',; ',setvar(_prnt_i,_prnt_i+1)))<>'' do  
   if delimpos(_prnt_tok,'./') <> 1 then                                        
      # skip HFS path elements, we have an MPE syntax element                   
      setvar _prnt_match (finfo("!filename.!_prnt_tok",'exists'))               
   endif                                                                        
endwhile                                                                        
                                                                                
#  Print "filename" to "out" if found.                                          
if _prnt_match then                                                             
   setvar _prnt_f fqualify("!filename.!_prnt_tok")                              
   echo !_prnt_f                                                                
   continue                                                                     
   print !_prnt_f,!out ;page=22                                                 
else                                                                            
   echo ![ups("!filename")] was not found in your HPPATH.                       
endif                                                                           
deletevar _prnt_@