PARM who="@S", days=7
# This script shows all jobs/sessions ("who") that have been logged
# on more than "days" days.  Requires 6.0 PP1 or later. Jeff Vance, CSY
#
if setvar(_jobcnt,JOBCNT("!who",_jobs)) = 0 then
   echo No job/sessions match "!who"
   return 
endif
# convert days to minutes
setvar _mins !days*60*24
echo
echo The job/sessions below have been connected more than !days days:
setvar i 0
while setvar(i,i+1) <= _jobcnt do
   if JINFO(setvar(_job,word(_jobs,,i)),"ConnectMin") > _mins then
      setvar _juag JINFO(_job,"JobUserAccountGroup")
      if lft(_job,1) = "S" then
         setvar _xtra JINFO(_job,"IPAddr")
         if _xtra = "" then
            setvar _xtra "LDEV: " + decimal(JINFO(_job,"LdevOut"))
         endif
      else
         setvar _xtra JINFO(_job,"StdlistSPID")+".OUT.HPSPOOL"
      endif
      echo   #!_job  ![rpt(" ",4-len(_job))] !_juag &
             ![rpt(" ",32-len(_juag))] !_xtra
   endif
endwhile
echo
deletevar _job,_jobcnt,_jobs,_xtra,i,_mins,_juag