PARM entry=main                                                                 
comment This script checks the current system for one or more configured HP-IB  
comment or FL Device Adapters.  If any are found they and the attached devices  
comment are reported.                                                           
comment   Jeff Vance, CSY  Apr 2000                                             
comment                                                                         
if "!entry" = "main" then                                                       
   echo                                                                         
   echo *** HP-IB and FL device checker for 5.0 and later MPE/iX systems ***    
   echo                                                                         
   setvar _hpib_conf_file "IOPATHP.CONFIG.SYS"                                  
                                                                                
   if not finfo(_hpib_conf_file, "exists") or &                                 
      setvar(_hpib_eof,finfo(_hpib_conf_file,"eof")) = 0 then                   
      echo  WARNING!!! The IO configuration file "!_hpib_conf_file" does not    
      echo  exist or is empty!                                                  
      echo                                                                      
      return                                                                    
   endif                                                                        
                                                                                
   comment read the IO config file                                              
   continue                                                                     
   xeq !hpfile read <!_hpib_conf_file                                           
                                                                                
   echo                                                                         
   echo         === S U M M A R Y ===                                           
   echo                                                                         
   echo ![rpt(" ",10-len("!_hpib_hpib_dam_cnt"))]!_hpib_hpib_dam_cnt  HP-IB &   
        Device Adapters                                                         
   echo ![rpt(" ",10-len("!_hpib_fl_dam_cnt"))]!_hpib_fl_dam_cnt  FiberLink &   
        Device Adapters                                                         
   echo ![rpt(" ",10-len("!_hpib_dev_cnt"))]!_hpib_dev_cnt  HP-IB and/or FL &   
        devices                                                                 
   echo                                                                         
   deletevar _hpib_@                                                            
   return                                                                       
                                                                                
elseif "!entry" = "read" then                                                   
   comment This entry read the IO conf file. Input is redirected to this file.  
   comment                                                                      
   setvar _hpib_hpib_dam_cnt 0                                                  
   setvar _hpib_fl_dam_cnt 0                                                    
   setvar _hpib_dev_cnt 0                                                       
                                                                                
   comment read the io config file                                              
   input _hpib_rec                                                              
   while setvar(_hpib_eof,_hpib_eof-1) >= 0 do                                  
      setvar _hpib_path ""                                                      
      if pos("HPIB_DAM",_hpib_rec) > 0 then                                     
         setvar _hpib_hpib_dam_cnt _hpib_hpib_dam_cnt+1                         
         setvar _hpib_path rtrim(str(_hpib_rec,2,16))                           
         echo   HP-IB Device Adapter at path !_hpib_path.  Card ID: &           
                ![str(_hpib_rec,42,16)]                                         
      elseif pos("ALINK_DAM",_hpib_rec) > 0 or &                                
             pos("NIO_ALINK_DAM",_hpib_rec) > 0 then                            
         setvar _hpib_fl_dam_cnt _hpib_fl_dam_cnt+1                             
         setvar _hpib_path rtrim(str(_hpib_rec,2,16))                           
         echo   FL Device Adapter at path !_hpib_path.  Card ID: &              
                ![str(_hpib_rec,42,16)]                                         
      endif                                                                     
                                                                                
      if _hpib_path <> "" then                                                  
         comment scan for the hp-ib or FL devices off this DAM                  
         setvar _hpib_save_eof _hpib_eof                                        
         while setvar(_hpib_eof,_hpib_eof-1) >= 0 and &                         
               pos(_hpib_path,setvar(_hpib_rec,input())) > 0 do                 
            setvar _hpib_dev_cnt _hpib_dev_cnt+1                                
            setvar _hpib_dev_path rtrim(str(_hpib_rec,2,16))                    
            echo      !_hpib_dev_path ![rpt(" ",12-len("!_hpib_dev_path"))] &   
                      ![str(_hpib_rec,34,26)]                                   
         endwhile                                                               
         comment adjust eof cntr for "read-ahead" feature above                 
         setvar _hpib_eof _hpib_eof+1                                           
         if _hpib_save_eof = _hpib_eof then                                     
            echo      (no devices for this DAM)                                 
         endif                                                                  
         echo                                                                   
      elseif _hpib_eof > 0 then                                                 
         comment read next record                                               
         input _hpib_rec                                                        
      endif                                                                     
   endwhile                                                                     
   return                                                                       
endif