&comment *******************************************************************    
&comment *** UPLOAD script:  uploads an item to the current Desk area    ***    
&comment *** from the PC.  Initially supports only text files and WRQ's  ***    
&comment *** Reflection.  Syntax is simply "UPLOAD" - it uses a dialog   ***    
&comment *** box on the PC to select the file, and HPDesk prompts them   ***    
&comment *** for the subject when the temporary file is copied in.       ***    
&comment ***                                                             ***    
&comment *** Author:  Jeff Kell   jeff_kell/admin@hpdesk.utc.edu         ***    
&comment ***          Administrative Computing Services, 117 Hunter Hall ***    
&comment ***          University of Tennessee at Chattanooga             ***    
&comment ***          Chattanooga, TN  37403   (615)-744-4551            ***    
&comment ***                                                             ***    
&comment *** 05/06/93:  Initial release.                                 ***    
&comment *******************************************************************    
&comment See if they're going to send text or binary                            
&forward 3 <not <parmpres 1>>                                                   
&save kind <parm 1>                                                             
&forward check                                                                  
$ask                                                                            
&print You must specify "T" for Text files or "B" for Binary files.  Note that  
&print Text files must be plain text such as Windows Notepad (*.TXT); Binary    
&print files include most word processors (Microsoft Word, WordPerfect, Write), 
&print program files, spreadsheets, and so forth.                               
&save kind <prompt "Are you uploading (T)ext or (B)inary? " "X" 1>              
$check                                                                          
&save kind <upshift <var kind>>                                                 
&forward 3 <not <equal <strpos "TBQ" <quote <var kind>>> 0>>                    
&print <chr 10> ** Please answer T or B to continue, or Q to quit ** <chr 10>   
&back ask                                                                       
&exit <strequal <quote <var kind>> "Q">                                         
&forward 2 <not <exists (zz<usernumber>)>>                                      
:purge zz<usernumber>                                                           
:setvar deskfence hpmsgfence                                                    
:setvar hpmsgfence 2                                                            
:continue                                                                       
:reset zz<usernumber>                                                           
:setvar hpmsgfence deskfence                                                    
:deletevar deskfence                                                            
&save refgo <esc>&oCSEND {} TO ZZ<usernumber>                                   
&forward 3 <strequal <quote <var kind>> "B">                                    
&save refgo <var refgo> ASCII<chr 13>                                           
&forward 3                                                                      
:file zz<usernumber>;code=1269                                                  
&save refgo <var refgo> BINARY<chr 13>                                          
&save result <prompt <quote <var refgo>> "F">                                   
&forward oops <strequal <quote <var result>> "F">                               
&forward oops <not <parmpres 2 result>>                                         
&forward oops <not <strequal <quote <parm 1 result>> "RUN">>                    
&save progname <makequoted <upshift <parm 2 result>>>                           
&save x <strpos <var progname> ";">                                             
&forward 3 <equal <var x> 0>                                                    
&save x <subtract <var x> 1>                                                    
&save progname <str <var progname> 1 <var x>>                                   
&forward 3 <strequal <var progname> "PCLINK.PUB.SYS">                           
&forward 2 <strequal <var progname> "PCLINK2.PUB.SYS">                          
&forward oops                                                                   
:xeq <parmrem 2 result>                                                         
&save result <prompt "" "F">                                                    
&forward oops <strequal <quote <var result>> "F">                               
&print Uploaded to holding area, copying to current area.                       
&forward 4 <strequal <quote <var kind>> "B">                                    
copy from (zz<usernumber>)                                                      
+Yes                                                                            
&forward 2                                                                      
copy from (zz<usernumber>)                                                      
:purge zz<usernumber>                                                           
&exit                                                                           
$oops                                                                           
&print *** Upload FAILED ***                                                    
&forward 2 <not <exists (zz<usernumber>)>>                                      
:purge zz<usernumber>                                                           
&exit