&comment *******************************************************************    
&comment *** RUN script:  Enables use of terminal emulator file transfer ***    
&comment *** to/from the host from inside HPDesk in a "secure" fashion.  ***    
&comment *** The HPDesk user need not have MPE access allowed, and the   ***    
&comment *** traditional "changing the host transfer startup string" fix ***    
&comment *** to the emulator is not required.  If you want to restrict   ***    
&comment *** both MPE and file transfers, you can add checks for HPDesk  ***    
&comment *** capability groups (or restrict access to the script).       ***    
&comment *** In order to work properly this script must be INSTALLed by  ***    
&comment *** the Desk Administrator with the name RUN, and NOT installed ***    
&comment *** as an application (else it will appear in the applications  ***    
&comment *** area... and as such isn't terribly useful!).                ***    
&comment ***                                                             ***    
&comment *** Author:  Jeff Kell   jeff_kell/admin@hpdesk.utc.edu         ***    
&comment ***          Administrative Computing Services, 117 Hunter Hall ***    
&comment ***          University of Tennessee at Chattanooga             ***    
&comment ***          Chattanooga, TN  37403   (615)-744-4551            ***    
&comment ***                                                             ***    
&comment *** 05/06/93:  Initial release.                                 ***    
&comment *******************************************************************    
&comment Make sure we're RUNning "something"                                    
&exit <not <parmpres 1>>                                                        
&save progname <makequoted <upshift <parm 1>>>                                  
&comment Most run with ;PARM= or ;INFO= and we just want the progname           
&save x <strpos <var progname> ";">                                             
&forward 3 <equal <var x> 0>                                                    
&save x <subtract <var x> 1>                                                    
&save progname <str <var progname> 1 <var x>>                                   
&comment Walker Richer & Quinn's Reflection uses PCLINK or PCLINK2              
&forward launch <strequal <var progname> "PCLINK.PUB.SYS">                      
&forward launch <strequal <var progname> "PCLINK2.PUB.SYS">                     
&comment MiniSoft's MS92 and WIN92 use MS92LINK or MS92LNK2                     
&forward launch <strequal <var progname> "MS92LINK.PUB.SYS">                    
&forward launch <strequal <var progname> "MS92LNK2.PUB.SYS">                    
&comment Tymlabs' Business Session and AdvanceLink for Windows use TYMLINK      
&forward launch <strequal <var progname> "TYMLINK.PUB.SYS">                     
&comment Old HP AdvanceLink uses MONITOR                                        
&forward launch <strequal <var progname> "MONITOR.PUB.SYS">                     
&print <chr 10>RUN is not supported in HPDesk.<chr 10>                          
&exit                                                                           
$launch                                                                         
&comment For MPE/V you should change this to :run, but on XL :xeq is used so    
&comment that the function keys don't disappear and HPDesk skips all the usual  
&comment overhead of setting up the application environment.                    
:xeq <parmrem 1>