&comment Script File Name: WPRINT                                               
&comment Date of Last Revision: 02/19/92                                        
&comment Revised by:  Bruce Marshall, WRQ TexSport (206 325-4357)               
&comment Last Revision closes and opens printer so Reflection 1                 
&comment for Windows will initiate printing.                                    
&comment                                                                        
&comment This script prints HPDesk items to a slaved printer                    
&comment                                                                        
&forward NONE <not <parmpres 1>>                                                
&forward IT <strequal <upshift <makequoted <parm 1>>> "IT">                     
&save SLASH <strpos <makequoted <parm 1>> "/">                                  
&forward SINGLE <equal <var SLASH> 0>                                           
&save END <strlen <makequoted <parm 1>>>                                        
&save FIRST <subtract <var SLASH> 1>                                            
&save NUM1 <str <makequoted <parm 1>> 1 <var FIRST>>                            
&save NUM1 <unquote <var NUM1>>                                                 
&save LAST <subtract <var END> <var SLASH>>                                     
&save NUM2 <str <makequoted <parm 1>> <add <var SLASH> 1> <var END>>            
&save NUM2 <unquote <var NUM2>>                                                 
&save COUNT <var NUM1>                                                          
&forward LOOP                                                                   
$NONE                                                                           
&save COUNT                                                                     
&forward LOOP                                                                   
$SINGLE                                                                         
&save COUNT <parm 1>                                                            
&save NUM2 1                                                                    
&forward LOOP                                                                   
$IT                                                                             
&save COUNT <refnum IT>                                                         
&save NUM2 1                                                                    
$LOOP    Main Program Loop                                                      
&pagelength 9999                                                                
&print <esc>&p11C                                                               
read <var COUNT>                                                                
&pagelength 24                                                                  
&print <esc>&p13C                                                               
&print <prompt "">                                                              
&print <esc>A<esc>A<esc>J                                                       
&forward DONE <equal <numeric <var COUNT>> 0>                                   
&save COUNT <add <var COUNT> 1>                                                 
&Comment Get out of Loop if no more parameters                                  
&forward DONE <greater <var COUNT> <var NUM2>>                                  
&back  LOOP                                                                     
$DONE  Exit the program                                                         
&Comment The next 2 lines issue Reflection commands.                            
&print <esc>&oFclose printer                                                    
&print <esc>&oFopen printer                                                     
&exit