&comment *******************************************************************    
&comment *** DOWNLOAD script:  downloads an item from the current Desk   ***    
&comment *** area to the PC.  Initially supports only text files and     ***    
&comment *** Reflection.  Syntax:                                        ***    
&comment ***    DOWNLOAD hpdesk-item                                     ***    
&comment *** where "hpdesk-item" can be an item number, a subject inside ***    
&comment *** quotation marks, or IT (it uses the REFNUM directive to     ***    
&comment *** interpret the item).  The user must have file save ability  ***    
&comment *** in the current group for this to work as a temporary file   ***    
&comment *** is used for the download.                                   ***    
&comment ***                                                             ***    
&comment *** Author:  Jeff Kell   jeff_kell/admin@hpdesk.utc.edu         ***    
&comment ***          Administrative Computing Services, 117 Hunter Hall ***    
&comment ***          University of Tennessee at Chattanooga             ***    
&comment ***          Chattanooga, TN  37403   (615)-744-4551            ***    
&comment ***                                                             ***    
&comment *** 05/06/93:  Initial release.                                 ***    
&comment *******************************************************************    
&comment Check to see at least a parameter is present                           
&forward showhelp <not <parmpres 1>>                                            
&comment See if we have a valid HPDesk item                                     
&save deskitem <parmrem 1>                                                      
$getitem                                                                        
&save deskitemno <refnum <var deskitem>>                                        
&forward 4 <not <equal 0 <var deskitemno>>>                                     
&print The specified desk item is invalid.                                      
&exit                                                                           
&comment Save the item type                                                     
&save dtype <type <var deskitemno>>                                             
&comment Is it a message?                                                       
&forward openit <equal <var dtype> -100>                                        
&comment Is it a folder?                                                        
&forward openit <equal <var dtype> -101>                                        
&comment Is it a package?                                                       
&forward openit <equal <var dtype> -102>                                        
&comment Is it a reply?                                                         
&forward openit <equal <var dtype> -300>                                        
&comment It should be a valid item then... go get it.                           
&forward getit                                                                  
$openit                                                                         
&print You cannot download an entire <typename <var dtype>>, OPENing instead... 
open <var deskitemno>                                                           
&save deskitem <prompt "Which item do you want to download? " "0">              
&back getitem                                                                   
$getit                                                                          
&comment Clear out a user-specific temp file                                    
&forward 2 <not <exists (zz<usernumber>)>>                                      
:purge zz<usernumber>                                                           
&Print Preparing to download <var deskitem>...                                  
copy <var deskitemno> to (zz<usernumber>)                                       
&comment Setup escape sequence to execute a Reflection RECEIVE command          
%&comment "&save refgo <esc>&oCRECEIVE {} FROM ZZ<usernumber> DELETE" works     
&save refgo <esc>&oCRECEIVE {} FROM ZZ<usernumber>                              
&comment Check to see if it is a PC-file, in which case make it BINARY          
&forward 2 <not <equal <var dtype> 1269>>                                       
&save refgo <var refgo> BINARY                                                  
&save refgo <var refgo><chr 13>                                                 
&comment Send escape sequence as a prompt for a read.  Note that we will *not*  
&comment get the F/S return code as expected -- we get the host startup string  
&save result <prompt <quote <var refgo>> "F">                                   
&forward oops <strequal <quote <var result>> "F">                               
&comment A few checks to be sure someone's not trying any foolishness           
&forward oops <not <parmpres 2 result>>                                         
&forward oops <not <strequal <quote <parm 1 result>> "RUN">>                    
&save progname <makequoted <upshift <parm 2 result>>>                           
&save x <strpos <var progname> ";">                                             
&forward 3 <equal <var x> 0>                                                    
&save x <subtract <var x> 1>                                                    
&save progname <str <var progname> 1 <var x>>                                   
&forward 3 <strequal <var progname> "PCLINK.PUB.SYS">                           
&forward 2 <strequal <var progname> "PCLINK2.PUB.SYS">                          
&forward oops                                                                   
:xeq <parmrem 2 result>                                                         
&comment And *NOW* we read the return code of the download                      
&save result <prompt "" "F">                                                    
&forward oops <strequal <quote <var result>> "F">                               
:purge zz<usernumber>                                                           
&exit                                                                           
$oops                                                                           
&print *** Download FAILED ***                                                  
:purge zz<usernumber>                                                           
&exit                                                                           
$showhelp                                                                       
&print DOWNLOAD will download an item in the current area to your PC.  You will 
&print be given a file dialog box to specify the filename and it's location.    
&print                                                                          
&print Syntax:  DOWNLOAD hpdesk-item                                            
&print                                                                          
&print The "hpdesk-item" can be the number of an item in the current area, or   
&print the subject of an item in the current area, similar to COPY parameters.